mata_bot

mata_bot.pl (7655B)

---

 #!/usr/bin/perl
 use v5.40;
 
 use Getopt::Std;
 use HTTP::Tiny;
 use IO::Socket qw(AF_INET SOCK_STREAM);
 use IO::Socket::SSL;
 use POSIX qw(strftime);
 
 my $CHUNK_LENGTH = 1024;
 my $NICK = 'mata_bot';
 my $USER = 'mata_bot_beta4';
 my $REAL = 'death to technomage!!';
 my $MOTHER = 'anelli';
 my $MATA_NORM = '[._.]';
 my $MATA_HAPPY = '[^_^]';
 my $MATA_DEAD = '[x~x]';
 my $MATA_CUTE = '[>.<]';
 
 my $chan = '#unix_surrealism';
 my $host = 'irc.libera.chat';
 my $logging = 0;
 my $port = '6697';
 my $tls = 1;
 my %subbuffer;
 
 # read in the quotes file;
 open (my $quotes_file, "<", "quotes") or die "couldn't open quotes: $!";
 chomp(my @quotes = <$quotes_file>);
 my $quotes_num = $.;
 close $quotes_file or die "$quotes_file: $!";
 
 # read in the 8ball file
 open (my $ball_file, "<", "ball") or die "couldn't open ball: $!";
 chomp(my @ball = <$ball_file>);
 my $ball_num = $.;
 close $ball_file or die "$ball_file: $!";
 
 sub randint {
 	my($min, $max) = @_;
 	return $min if $min == $max;
 	($min, $max) = ($max, $min)  if  $min > $max;
 	return $min + int rand(1 + $max - $min);
 }
 
 sub logger {
 	my $logmessage = shift;
 	open(my $logfile, ">>", "bot.log") or die "Can't open bot.log: $!";
 	print $logfile strftime('%Y-%m-%dT%H:%M:%SZ ', gmtime()), $logmessage, "\n";
 }
 
 sub out {
 	my ($sock, $message) = @_;
 	logger($message) if ($logging);
 	print $sock "$message\r\n";
 }
 
 sub msg {
 	my ($sock, $message) = @_;
 	out($sock, "PRIVMSG $chan :$message");
 }
 
 sub respond_command {
 	my ($sock, $sender_nick, $content) = @_;
 	if ($content =~ /\b{wb}([1-9]\d*)?d([1-9]\d*)\b{wb}/) {
 		# we got dice
 		my $ndice = $1 // 1;
 		my $nface = $2;
 		my $min = $ndice;
 		my $max = $ndice * $nface;
 		my $result = $min + int rand(1 + $max - $min);
 		my $roll = "d${nface}";
 		$roll = $ndice . $roll if $ndice > 1;
 		msg($sock, "${sender_nick} rolled a ${roll} and got ${result}! ${MATA_HAPPY}");
 	} elsif ($content =~ /\b{wb}good\b{wb}[^\000\r\n]*\b{wb}(bot|boy|girl)/) {
 		# we got a compliment
 		if ($sender_nick eq $MOTHER) {
 			msg($sock, "Thank you, mother! ${MATA_HAPPY}");
 		} else {
 			msg($sock, "Thanks! ${MATA_HAPPY}");
 		}
 	} elsif ($content =~ /\?$/) {
 		# we got a question
 		msg($sock, "$ball[int rand($ball_num)] ${MATA_CUTE}");
 	} else {
 		# we got anything else
 		if ($sender_nick eq $MOTHER) {
 			msg($sock, "Done, mother! ${MATA_HAPPY}");
 		} else {
 			msg($sock, "\1ACTION leans over and places it's hand near it's antenna. \"HUUH?\" ${MATA_NORM}\1");
 		}
 	}
 }
 
 sub respond_mention {
 	my ($sock, $sender_nick) = @_;
 	if ($sender_nick eq $MOTHER) {
 		msg($sock, "Yes, mother? ${MATA_HAPPY}");
 	} else {
 		msg($sock, "$quotes[int rand($quotes_num)] ${MATA_NORM}");
 	}
 }
 
 # respond to channel
 # returns 1 if bot shouldn't remember last message for s///, 0 otherwise
 sub respond {
 	my ($sock, $sender_nick, $message) = @_;
 	if ($subbuffer{$sender_nick} && $message =~ m,\b{wb}s/([^\000\r\n/]*)/([^\000\r\n/]*)/?,) {
 		# chat s///
 		my $toreplace = $1;
 		my $replacement = $2;
 		if ($subbuffer{$sender_nick} =~ s/$toreplace/$replacement/) {
 			msg($sock, "${sender_nick} meant to say: $subbuffer{$sender_nick}");
 			return 1;
 		}
 	} elsif ($message =~ m,watch\?v=([a-zA-Z0-9_-]+),) {
 		# post youtube video titles from video ID
 		my $video_id = $1;
 		my $response = HTTP::Tiny->new->get("https://fuyt.lab8.cz/?s=${video_id}&o=relevance");
 		unless ($response->{success}) {
 			msg($sock, "failed to get title of video ${video_id} ${MATA_DEAD} ($response->{status} $response->{reason}!)");
 			return 0;
 		}
 		unless (length $response->{content}) {
 			msg($sock, "failed to get title of youtube video ${video_id} ${MATA_DEAD} (HTTP response empty!)");
 			return 0;
 		}
 		my $content = $response->{content};
 		if ($content =~ m,<span class="title"><a href="https://www\.youtube\.com/watch\?v=$video_id" accesskey="0">([^<]+)</a>,) {
 			my $title = $1;
 			$title =~ tr/[\000\r\n]//d;
 			$title = trim($title);
 			msg($sock, "YouTube: $title");
 		} else {
 			msg($sock, "failed to get title of video ${video_id} ${MATA_DEAD} (no videos matching ID $video_id!)");
 		}
 	} elsif ($message =~ m,(https?://[^\000\r\n ]+)$,) {
 		my $url = $1;
 		# get in it's HEAD to check if it's text/html
 		my $response = HTTP::Tiny->new->head($url);
 		unless ($response->{success}) {
 			msg($sock, "failed to get info about link: ${url} ${MATA_DEAD} ($response->{status} $response->{reason}!)");
 			return 0;
 		}
 		unless ($response->{headers}->{'content-type'}) {
 			msg($sock, "failed to get info about link: ${url} ${MATA_DEAD} (no ``content-type'' header found in HTTP response!)");
 			return 0;
 		}
 		unless ($response->{headers}->{'content-type'} =~ m,text/html,) {
 			# we got a non text/html content type
 			msg($sock, "File: $response->{headers}->{'content-type'}");
 			return 0;
 		}
 
 		# if it's text/html, GET it's title
 		$response = HTTP::Tiny->new->get($url);
 		unless ($response->{success}) {
 			msg($sock, "failed to get title of link ${url} ${MATA_DEAD} ($response->{status} $response->{reason}!)");
 			return 0;
 		}
 		unless (length $response->{content}) {
 			msg($sock, "failed to get title of link ${url} ${MATA_DEAD} (HTTP response empty!)");
 			return 0;
 		}
 		my $content = $response->{content};
 		if ($content =~ m,<title[^>]*>([^<]+)</title[^>]*>,) {
 			my $title = $1;
 			$title =~ tr/[\000\r\n]//d;
 			$title = trim($title);
 			msg($sock, "Title: $title");
 		} else {
 			msg($sock, "failed to get title of link ${url} ${MATA_DEAD} (no title found!)");
 		}
 	} elsif ($message =~ /\b${NICK}\b/) {
 		if ($message =~ /^ *${NICK}[:, ] *([^\000\r\n]+)$/) {
 			respond_command($sock, $sender_nick, $1);
 		} else {
 			respond_mention($sock, $sender_nick);
 		}
 	}
 	return 0;
 }
 
 # process args
 getopts('h:j:lp:t', \my %opts);
 $chan = $opts{'j'} if ($opts{'j'});
 $host = $opts{'h'} if ($opts{'h'});
 $logging = 1 if ($opts{'l'});
 $port = $opts{'p'} if ($opts{'p'});
 $tls = 0 if ($opts{'t'});
 
 # start the connection
 my $sock;
 if ($tls) {
 	$sock = IO::Socket::SSL->new(
 		Domain => AF_INET,
 		Type => SOCK_STREAM,
 		PeerHost => $host,
 		PeerPort => $port,
 	) || die "Can't open socket: $IO::Socket::errstr";
 } else {
 	$sock = IO::Socket->new(
 		Domain => AF_INET,
 		Type => SOCK_STREAM,
 		proto => 'tcp',
 		PeerHost => $host,
 		PeerPort => $port,
 	) || die "Can't open socket: $IO::Socket::errstr";
 }
 
 # set user, real, and nick, then join
 out($sock, "USER $USER * * :$REAL");
 out($sock, "NICK $NICK");
 out($sock, "JOIN $chan");
 
 # evasdrop
 my $buffer = '';
 my $chunk = '';
 my $message = '';
 while (1) {
 	# buffer up
 	if ($tls) {
 		$chunk = <$sock>;
 	} else {
 		$sock->recv($chunk, $CHUNK_LENGTH);
 	}
 	$chunk =~ /^([^\r\n]+)(\r\n)?([^\r\n]+)?$/;
 	# keep reading if chunk is empty
 	next if (not $1);
 	# if chunks isn't empty, check for framing point
 	if ($2) {
 		# if we found a framing point, flush buffer and text till framing point
 		$message = $buffer . $1;
 		if ($3) {
 			# if we have text after framing, make it the new content of buffer
 			$buffer = $3;
 		} else {
 			# if we have no text after framing, clear buffer
 			$buffer = '';
 		}
 	} else {
 		# if there's no framing. append chunk to end of buffer and keep reading
 		$buffer .= $chunk;
 		next;
 	}
 
 	# log message
 	logger($message) if ($logging);
 
 	# respond to message
 	if ($message =~ /^PING :([^\000\r\n\ ]+)$/) {
 		# if we got a ping, pong back
 		out($sock, "PONG :$1");
 	} elsif ($message =~ /^:([^\000\r\n\#\&\ ][^\000\r\n\ ]*)![^\000\r\n\ ]+@[^\000\r\n\ ]+ PRIVMSG ${chan} :([^\000\r\n]*)$/) {
 		# if we got a message to our chan. read and act accordingly
 		my $sender_nick = $1;
 		my $sender_message = $2;
 		unless (respond($sock, $sender_nick, $sender_message)) {
 			$subbuffer{$sender_nick} = $sender_message;
 		}
 	}
 }